详解Androidstudiondk配置cmake开发nativeC

Android 2.2 以后的版本对NDK的支持已经非常好了。最近把一个纯C的android项目，从eclipse ADT迁移到Android studio上。本文是参考Add C and C++ Code to Your Project 官方文档(需要翻墙)，经过各种尝试之后的总结。

为江城等地区用户提供了全套网页设计制作服务，及江城网站建设行业解决方案。主营业务为网站设计制作、成都网站设计、江城网站设计，以传统方式定制建设网站，并提供域名空间备案等一条龙服务，秉承以专业、用心的态度为用户提供真诚的服务。我们深信只要达到每一位用户的要求，就会得到认可，从而选择与我们长期合作。这样，我们也可以走得更远！

Android studio整合NDK开发，有两种模式，一种是ndk build，一种是cmake，如果是新项目官方推荐cmake。原来，ADT的时候只能用ndk build，这次切换IDE并没有选用ndk build，而是尝试了cmake感觉上配置更加简洁方便。

本文探讨一下几点：

1. 迁移现有native C代码使用cmake，如果是新项目同理更加简单。
2. 项目是native activity就是没有java代码的纯native project。
3. 构建编译出多个so文件，并有依赖关系。
4. 使用不依赖IDE目录结构的代码目录。
5. 创建过程中的注意事项。

创建native项目，可以有两个选项。第一个是创建的时候，选择带有C++ Support功能的。

详解Android studio ndk配置cmake开发native C

第二个是对已有工程添加c/c++功能。这里，无论是不是新项目，都推荐使用创建一个项目在添加c/c++功能，这样native code就可以独立于项目放在任意目录。创建一个没有native code工程，在根据CMakeLists.txt文件来添加NDK的支持。File -> Link C++ Project with Gradle。

详解Android studio ndk配置cmake开发native C

这样，我们的代码就可以独立于IDE的目录结构。只要提供CMakeLists.txt文件即可。一旦我们提供了CMakeLists.txt文件，Android studio就会根据这个文件为我们在工程下面生成一个cpp文件夹用来存放CMakeLists.txt里面配置的native代码文件。

详解Android studio ndk配置cmake开发native C

下面我们来快速的介绍一下CMakeLists.txt基本功能的写法，能够应付通常的情况。更多丰富的使用规则需要查看官方文档。CMake documentation。

# Sets the minimum version of CMake required to build the native 
# library. You should either keep the default value or only pass a 
# value of 3.4.0 or lower. 
 
cmake_minimum_required(VERSION 3.4.1) 
 
##################################################################### 
 
# 这个是设置了编译C的参数，这里使用C99并开启三级优化 
# 类似的设置还有CMAKE_CPP_FLAGS就是设置编译C++的参数 
# 更多的参数就要根据需要看文档了 
set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -O3 -std=c99") 
 
##################################################################### 
 
# 这个函数是用来编译库的，主要是so文件和a文件。 
add_library( # 括号不在这一行语法错误 
  # 库的名字自定义的 
  PNG    
 
  # static 就是a文件，shared 就是so文件  
  STATIC   
 
  # 这里提供的是预编译好的文件，所以用这个imported， 
  # 否则需要提供需要编译文件的列表 
  IMPORTED  
) 
 
# 设置编译库文件的属性，有很多属性设置，根据需要查看文档 
set_target_properties( 
  # 设置哪个库的编译属性 
  PNG         
 
  # 上面的PNG库是预编译的，这里的属性表示文件所在的位置 
  PROPERTIES IMPORTED_LOCATION  
                 
  # 提供预编译文件的位置。 
  # CMAKE_SOURCE_DIR 是内置变量表示当前CMakeLists.txt的位置。 
  # 这里需要提供绝对路径所以需要这个变量， 
  # 下面会看到所有的设置都是相对于当前文件的。但这个设置需要绝对路径。 
  # ANDROID_ABI内置变量，会根据当前编译的平台分配一个文件夹名字， 
  # 比如armeabi-v7a， armeabi，x86等等 
  ${CMAKE_SOURCE_DIR}/PNG/Prebuilt/Android/${ANDROID_ABI}/libpng.a 
) 
 
##################################################################### 
 
# 表示编译文件时候，头文件的位置。路径是相对于当前文件的 
# 正确设置了这个路径，在IDE中代码头文件也会正确索引。否则会无法定位头文件。 
# 这里我们提供了代码的文件的根目录和PNG库的头文件目录 
include_directories( 
  ../../../ 
  ../../External/PNG/Include/Android/ 
) 
 
# 另外一个用法。编译so文件，自定义名字叫做NativeLib 
# 就像NDK Build的配置一样，需要把源文件列表提供，不需要头文件。 
# 这些源文件会编译成一个NativeLib.so文件。 
# 值得一提的时候，在NDK Build中，我编译一个没有源文件的so文件， 
# 以后把其他的a文件整体连接进来。这里不行，必须提供源文件至少一个。 
add_library( 
  NativeLib SHARED 
 
  ../../Toolkit/Toolkit.c 
  ../../Toolkit/Math/Math.c 
  ../../Toolkit/Math/Matrix.c 
  ../../Toolkit/Math/TweenEase.c 
  ../../Toolkit/Utils/Array.c 
  ../../Toolkit/Utils/ArrayList.c 
  ../../Toolkit/Utils/ArrayStrMap.c 
  ../../Toolkit/Utils/ArrayIntMap.c 
  ../../Toolkit/Utils/ArrayQueue.c 
  ../../Toolkit/Utils/BufferReader.c 
  ../../Toolkit/Utils/Json.c 
  ../../Toolkit/Utils/Tween.c 
  ../../Toolkit/Utils/TweenTool.c 
  ../../Toolkit/Platform/File.c 
) 
 
# 这是编译一个a文件。可见此函数可以使用任意多个，编译出多个库文件。 
add_library( 
  EntryLink STATIC 
  ../../Application/EntryLink.c 
) 
 
# 这是连接一个库文件。在库文件使用了平台，或是预编译库的接口文件，就需要在此连接。 
# 才能在运行时正确调用到这些接口函数。 
target_link_libraries( 
  # 需要连接的库名字，上面定义的任何一个库都行。 
  NativeLib 
   
  # 这里奇怪的参数，是让PNG这个库直接拷贝到NativeLib里面。 
  # 因为并不打算把PNG这个库单独载入，平台也不一定有这个库， 
  # 于是就整体复制到NativeLib.so里面 
  "-Wl,--whole-archive"   
  PNG   
  "-Wl,--no-whole-archive"   
   
  # 这个库存在的意义是 
  # 比如我在NativeLib用到了一些接口函数，希望留给另外一个库使用。 
  # 连接的时候，不提供另外一个库，或是那个库还没编译。就会连接失败找不到函数实现。 
  # 所以我们用这个库实现空的函数，用作连接。 
  # 并不会放到NativeLib.so里。真正运行的时候，有别的so库文件提供。 
  EntryLink   
 
  # 以下就是Android平台提供的库直接写名字就行了。官方文档有说明哪些。 
  android        
  EGL   
  GLESv2   
  log   
  z 
)

那么编译出来的库文件在为什么位置呢，如下:

详解Android studio ndk配置cmake开发native C

系统生成apk的时候，会自动安装进去。那么，有些情况，能不能自己控制库文件的输出的目录能。当然是可以的，参看NDK官方的例子，hello-libs。

add_library(gmath STATIC src/gmath.c) 
set_target_properties(gmath 
           PROPERTIES 
           # 拷贝到下面的指定目录，注意这个属性名，这是拷贝a文件的。 
           ARCHIVE_OUTPUT_DIRECTORY  
           ${CMAKE_CURRENT_SOURCE_DIR}/lib/${ANDROID_ABI}) 
 
add_library(gperf SHARED src/gperf.c) 
set_target_properties(gperf 
           PROPERTIES 
           # 拷贝到下面的指定目录，注意这个属性名，这是拷贝so文件的。 
           LIBRARY_OUTPUT_DIRECTORY  
           ${CMAKE_CURRENT_SOURCE_DIR}/lib/${ANDROID_ABI})

接下来的问题就是，如果我有多个不同库功能不同，源码很多不能放在一起编译。希望能够模块化管理，有两个方案。

第一个方案，给工程添加一个依赖模块，用同样的方法link一个CMakeLists.txt这样。如果这样，工程就有两个模块不同的gradle配置，就需要我们用上面的方法把作为库文件产生的so文件编译到指定目录下面，在添加预编译文件的方式进行连接。我开始是用的这个方法，可以工作但感觉并不好，NDK的例子hello-libs也是用的这个方法。后来我发现了一个跟简单的方法。

第二个方案，利用CMake的add_subdirectory函数，可以添加一个子目录，去让CMakeLists.txt再去载入另外一个CMakeLists.txt。这正是我们需要方法。类似于NDK Build里面的嵌套mk文件。

两种方案都会把多个CMakeLists.txt文件导入到Android Studio里面。

详解Android studio ndk配置cmake开发native C

# Sets the minimum version of CMake required to build the native 
# library. You should either keep the default value or only pass a 
# value of 3.4.0 or lower. 
 
cmake_minimum_required(VERSION 3.4.1) 
 
set(CMAKE_VERBOSE_MAKEFILE ON) 
 
##################################################################### 
 
# 第一个参数表示需要加载的子目录CMakeLists.txt文件目录 
# 第二个参数表示编译这个文件内容的中间文件目录 
# 都是绝对路径，所以我们使用了内置变量，来跨平台 
add_subdirectory( 
  ${CMAKE_SOURCE_DIR}/../../../NativeLib/Build/Android/ 
  ${CMAKE_SOURCE_DIR}/../../../NativeLib/Build/Android/Bin/ 
) 
 
##################################################################### 
 
include_directories( 
  ../../../ 
) 
 
add_library( 
  Development SHARED 
 
  ../AppInit.c 
  ../Tool.c 
  ../GameMap.c 
  ../Hero.c 
  ../Enemy.c 
  ../EnemyAI.c 
  ../GameActor.c 
) 
 
##################################################################### 
 
target_link_libraries( 
  Development 
  NativeLib 
)

如上，我们把NativeLib作为库编译，Development依赖这个库。需要注意的是，在子目录的CMakeLists.txt中内置变量CMAKE_SOURCE_DIR是父目录的值，而不是当前文件目录。另外，可以看到我们编译出了两个so文件，链接它们。这样在java中就需要载入两个so文件。其实我是想合并两个so的，但是利用"-Wl,--whole-archive"属性的时候，会发生libc.so里面很多重定义。经过google发现这个可能是NDK的一个bug并没有修复。

当然，也可以只生成一个so文件。就是让NativeLib编译为STATIC的，然后在Development target_link_libraries的时候使用"-Wl,--whole-archive"完全把NativeLib的a文件合并到Development里面就可以了。

最后，就是一个Gradle的配置了。

apply plugin: 'com.android.application' 
 
android { 
  compileSdkVersion 23 
  buildToolsVersion '25.0.0' 
  defaultConfig { 
    applicationId 'com.test.development' 
    minSdkVersion 19 
    targetSdkVersion 23 
    versionCode 1 
    versionName '1.0' 
    ndk { 
      // 这里控制NDK编译哪些类型的ABI so文件，用来适配不同平台 
      abiFilters 'armeabi-v7a' 
    } 
    externalNativeBuild { 
      // 使用cmake，还可以使用ndk 
      cmake { 
        arguments '-DANDROID_TOOLCHAIN=clang',  
             '-DANDROID_STL=system' 
        cFlags  '-std=c99' 
      } 
    } 
  } 
  buildTypes { 
    release { 
      minifyEnabled false 
      proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro' 
    } 
  } 
  externalNativeBuild { 
    cmake { 
      // 定位文件，link的时候自动生成 
      path '../../Build/Android/CMakeLists.txt' 
    } 
  } 
} 
 
dependencies { 
  compile fileTree(include: ['*.jar'], dir: 'libs') 
}

cmake的参数配置，arguments可以参看官方文档 Using CMake Variables，更多的gradle cmake配置在这里 Configure Build Types，需要科学上网。当然也可以自定义自己需要的参数，比如fire_base_sdk_dir用在cmake的配置中。

以上就是本文的全部内容，希望对大家的学习有所帮助，也希望大家多多支持创新互联。

标题名称：详解Androidstudiondk配置cmake开发nativeC
网页链接：http://chengdu.cdxwcx.cn/article/ijjcps.html

甜橘子，专注成都网站制作网站设计与营销型网站建设与优化

首页

网站建设

网站制作案例

解决方案

网站设计报价

网站制作动态

关于我们

联系我们

成都网站建设设计将想法与焦点和您一起共享

详解Androidstudiondk配置cmake开发nativeC

其他资讯

windows中mathtype文字大小如何改

微信开发中如何实现微信jsapi选择图片,上传图片,预览和下载图片的方法

如何借助log4j把日志写入数据库中

php如何实现每天积分加一

es7之fetch如何解决异步嵌套问题

甜橘子，专注成都网站制作网站设计与营销型网站建设与优化

成都网站建设设计 将想法与焦点和您一起共享

详解Androidstudiondk配置cmake开发nativeC

其他资讯

windows中mathtype文字大小如何改

微信开发中如何实现微信jsapi选择图片,上传图片,预览和下载图片的方法

如何借助log4j把日志写入数据库中

php如何实现每天积分加一

es7之fetch如何解决异步嵌套问题

成都网站建设设计将想法与焦点和您一起共享